0 CLS3:X=31:Y=15:DIMM(X,Y):FORJ=1TOY-1:M(0,J)=10:M(X,J)=10:NEXT:FORI=1TOX-1:M(I,0)=5:M(I,Y)=5:NEXT:X=10:Y=10:I=X:J=Y:X(1)=-1
1 X(3)=1:Y(2)=1:Y(4)=-1:Z(1)=1:Z(2)=2:Z(3)=4:Z(4)=8:Q(1)=772:Q(2)=1032:Q(3)=257:Q(4)=514:A=RND(-(PEEK(9)*256+PEEK(10)))
2 POKE49151,28:A=0:FORC=1TO4:IFM(X+X(C),Y+Y(C))=0THENV(A)=C:A=A+1
3 NEXT:ON-(A=0ANDX=10ANDY=10)GOTO6:IFA=0THENR=INT(M(X,Y)/256):GOTO5
4 B=RND(A+1)-1:ON-(B>=A)GOTO4:R=V(B):IFRTHENM(X,Y)=M(X,Y)ORZ(R):M(X+X(R),Y+Y(R))=Q(R)
5 X=X+X(R):Y=Y+Y(R):RESET(X*2,Y*2):RESET(X*2+SGN(I-X),Y*2+SGN(J-Y)):I=X:J=Y:GOTO2
6 SOUND200,5:X=2:Y=2:Q=1000:PRINT@479,"";:RESET(61,28):PRINT@496,"HIGH"HS"";:IFSC>HSTHENHS=SC:PRINT@496,"HIGH"HS;
7 SET(X,Y,3):A=PEEK(2)ANDPEEK(17023):I=(A=65)-(A=68):J=(A=87)-(A=83):B=POINT(X+I,Y+J):IFB=0THENRESET(X,Y):X=X+I:Y=Y+J
8 Q=Q-1:PRINT@480,"TIME"Q,:RESET(X,Y):FORC=1TO25:NEXT:ON-(B<>2ANDQ>0)GOTO7:PRINT"SAME MAZE?";:SC=Q:IFQ=0THENSOUND1,10
9 I$=INKEY$:R=RND(999):ON-(I$="")GOTO9:ON-(I$="Y")GOTO6:ON-(I$<>"N")GOTO9:SOUND109,4:SOUND53,2:SOUND134,8:RUN
10 REM IN THIS GAME YOU MUST
11 REM SOLVE THE MAZE IN THE
12 REM SHORTEST TIME POSSIBLE.
13 REM YOU START AT TOP LEFT.
14 REM USE wasd TO GET THE
15 REM CHEESE IN LOWER RIGHT.
16 REM HIT y FOR ANOTHER PLAYER
17 REM TO HAVE A TRY OR n TO
18 REM RESTART THE GAME.
19 REM JIM GERRIE 10-LINER 2018
